build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.3.30'
    id 'org.jetbrains.kotlin.plugin.spring' version '1.3.30'
    id 'org.springframework.boot' version '2.1.4.RELEASE'
    id 'com.jfrog.bintray' version '1.8.4'
}

allprojects {
    group = 'io.zensoft.hootka'
    version = '1.0.0'

    repositories {
        mavenCentral()
    }
}

ext {
    kotlinVersion = '1.3.30'
    nettyVersion = '4.1.21.Final'
}

subprojects {
    apply plugin: 'maven'
    apply plugin: 'kotlin'
    apply plugin: 'kotlin-spring'
    apply plugin: 'org.springframework.boot'
    apply plugin: 'io.spring.dependency-management'
    apply plugin: 'maven-publish'
    apply plugin: 'com.jfrog.bintray'

    sourceCompatibility = JavaVersion.VERSION_1_8

    dependencies {
        compile('org.springframework.boot:spring-boot-starter')
        compile("org.springframework.boot:spring-boot-configuration-processor")
        compile('org.springframework.security:spring-security-crypto')
        compile("io.netty:netty-all:${nettyVersion}")

        compile("org.freemarker:freemarker:2.3.23")

        // Utilities
        compile('com.github.ben-manes.caffeine:caffeine:2.6.2')

        compile('org.apache.commons:commons-lang3:3.1')
        compile('commons-io:commons-io:2.6')

        // Kotlin
        compile("org.jetbrains.kotlin:kotlin-stdlib-jdk8:${kotlinVersion}")
        compile("org.jetbrains.kotlin:kotlin-reflect:${kotlinVersion}")
        compile("com.fasterxml.jackson.module:jackson-module-kotlin:2.9.4.1")
        compile('com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.9.3')

        // Validation
        compile("javax.validation:validation-api:2.0.0.Final")
        compile("javax.el:javax.el-api:3.0.0")
        compile("org.glassfish:javax.el:3.0.0")
        compile("org.hibernate.validator:hibernate-validator:6.0.1.Final")

    }

    task sourcesJar(type: Jar, dependsOn: classes) {
        classifier = 'sources'
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier = 'javadoc'
        from javadoc.destinationDir
    }
    // Jar
    jar {
        manifest {
            attributes("Implementation-Version": version)
        }
    }

    bootJar.enabled = false
    jar.enabled = true

    // Kotlin
    compileKotlin {
        kotlinOptions {
            jvmTarget = "1.8"
        }
    }
    compileTestKotlin {
        kotlinOptions {
            jvmTarget = "1.8"
        }
    }
    sourceSets {
        main.kotlin.srcDirs += 'src/main/kotlin'
    }

    publishing {
        publications {
            maven(MavenPublication) {
                from components.java

                artifact sourcesJar
                artifact javadocJar
            }
        }
    }

    artifacts {
        archives sourcesJar
    }

    bintray {
        user = System.getenv("BINTRAY_USER") ?: System.properties['bintrayUser']
        key = System.getenv("BINTRAY_KEY") ?: System.properties['bintrayKey']
        configurations = ['archives']

        pkg {
            repo = "maven"
            name = project.name
            licenses = ['Apache-2.0']
            vcsUrl = 'https://github.com/zensoftio/hootka.git'
        }
    }
}

bintrayUpload.enabled = false
bootJar.enabled = false