common.gradle

/*
 * The MIT License (MIT)
 *
 * Copyright (c) SKrypton by waicool20
 *
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 */

import org.gradle.internal.os.OperatingSystem

OperatingSystem currentOS = OperatingSystem.current()

static Boolean is32Bit() {
    return !is64Bit()
}

static Boolean is64Bit() {
    return System.getProperty("os.arch").contains("64")
}

static Boolean commandExists(String command) {
    try {
        Runtime.runtime.exec(command)
        return true
    } catch (Exception ignored) {
        return false
    }
}

static String getPublishAPIKey() {
    String key = System.getenv("PUBLISH_API_KEY")
    if (key == null) println("Publishing API key not found, it might not be set.")
    return key
}

static String getBintrayKey() {
    String key = System.getenv("BINTRAY_KEY")
    if (key == null) println("Bintray key not found, it might not be set.")
    return key
}

def commonPom = {
    resolveStrategy = Closure.DELEGATE_FIRST
    description "A browser automation library that uses SikuliX and doesn't grab your mouse."
    url "https://github.com/waicool20/SKrypton"
    packaging "jar"
    licenses {
        license {
            name "The MIT License (MIT)"
            url "http://opensource.org/licenses/MIT"
            distribution "repo"
        }
    }
    developers {
        developer {
            name "waicool20"
            email "waicool20@gmail.com"
            organization "waicool20"
            organizationUrl "https://www.waicool20.com"
        }
    }
    scm {
        url "https://github.com/waicool20/SKrypton"
        connection "scm:git:git://github.com/waicool20/SKrypton.git"
        developerConnection "scm:git:ssh://github.com/waicool20/SKrypton.git"
    }
}


ext {
    ext.isLinux = currentOS.isLinux()
    ext.isWindows = currentOS.isWindows()
    ext.isMacOsX = currentOS.isMacOsX()
    ext.isUnix = currentOS.isUnix()
    ext.is32Bit = is32Bit()
    ext.is64Bit = is64Bit()
    ext.commandExists = this.&commandExists
    ext.commonPom = commonPom

    ext.cmakeBuildDebugDir = 'cmake-build-debug'
    ext.cmakeBuildReleaseDir = 'cmake-build-release'

    ext.publishApiKey = getPublishAPIKey()
    ext.bintrayKey = getBintrayKey()

    if (currentOS.isLinux()) {
        ext.osName = "Linux"
    } else if(currentOS.isWindows()) {
        ext.osName = "Windows"
    } else if(currentOS.isMacOsX()) {
        ext.osName = "MacOsX"
    } else {
        ext.osName = "Unknown"
    }
}