Attempt to recover from invalid spell items

Gothic encounters an unrecoverable error when unarchiving oCNpcInventory
and facing an equipped spell item (scroll or rune) that no longer exists
in the game scripts. This is due to an extra archive-value that will not
be skipped when continuing to the next item. While this error is native
to Gothic, it is more likely to happen if a patch introduces a spell
item, that item is equipped and the patch is removed. While corrupt
binary archives are unrecoverable, and the game will crash with
certainty, this commit introduces an attempt to recover, by advancing
the buffer beyond a potential extra archive-value and tries to read the
item object again. Note that this will guarantee to solve the above
issue, but that issue only.

Author: szapp

Makefile

@@ -141,6 +141,7 @@ BIN_BASE		:=	core										\
 					hook_archiveWorldWriteLogicalNpc			\
 					hook_oCSpawnManager__Archive				\
 					hook_npcReference							\
+					hook_recoverInvalidItem						\
 					hook_fastexit								\
 					hook_CGameManager_destructor				\
 					hook_libExit								\

src/exec/misc.asm

@@ -243,6 +243,51 @@ removeNpcInstRef:
         jmp     g1g2(0x68C0F6,0x6BC7DD,0x6D0445,0x72E625) + 5
 
 
+global recoverInvalidItem
+recoverInvalidItem:
+    resetStackoffset g1g2(0x94,0x94,0x100,0x100)
+        test    esi, esi                                                   ; Check for invalid item in archive
+        jnz     .back
+
+        sub     esp, 0x10                                                  ; At this point the error already happened:
+        push    char_shortKey                                              ; Attempt to recover by reading shortKey
+        lea     eax, [esp+0x4]                                             ; This advances the buffer to try again
+        push    eax
+        call    DWORD [ds_lstrcpyA]                                        ; Construct 'shortKeyX' on stack
+    addStack 2*4
+        push    0xA
+        lea     eax, [esp+0x4+0x8]                                         ; Stack-offset + len('shortKey')
+        push    eax
+        mov     ecx, [esp+stackoffset-g1g2(0x80,0x80,0xEC,0xEC)]           ; Index X
+        push    ecx
+        call    _itoa                                                      ; 'shortKey' + 'X', 0
+        add     esp, 0xC
+
+        mov     eax, [g1g2(ebp,ebp,ebx,ebx)]                               ; Attempt to advance buffer
+        lea     ecx, [esp+stackoffset-g1g2(0x78,0x78,0xE0,0xE0)]           ; Key-variable used as sink
+        push    ecx                                                        ; Arg1 key
+        mov     edx, esp                                                   ; Arg0 'shortKeyX'
+        mov     ecx, g1g2(ebp,ebp,ebx,ebx)                                 ; This zCArchive*
+        call    [eax+0x60]                                                 ; zCArchive->ReadInt
+    addStack 4
+        add     esp, 0x10                                                  ; Free 'shortKeyX' from stack
+
+        mov     edx, [esp+stackoffset-g1g2(0x68,0x68,0xBC,0xBC)]           ; Get existing 'itemX' and try again
+        mov     esi, [g1g2(ebp,ebp,ebx,ebx)]
+        push    0x0
+        mov     ecx, g1g2(ebp,ebp,ebx,ebx)
+        call    [esi+0xAC]                                                 ; zCArchive->ReadObject
+    addStack 4
+        mov     esi, eax
+    verifyStackoffset g1g2(0x94,0x94,0x100,0x100)
+
+.back:
+%if GOTHIC_BASE_VERSION == 1 || GOTHIC_BASE_VERSION == 112
+        mov     DWORD [esp+stackoffset-0x78], 0xFFFFFFFF
+%endif
+        jmp     g1g2(0x66DC47,0x69B420,0x6AFBB9,0x70D6D9) + 6
+
+
 global ninja_injectInfo
 ninja_injectInfo:
         resetStackoffset                                                   ; 0xBC

src/hook_recoverInvalidItem.asm

@@ -0,0 +1,29 @@
+; Hook oCNpcInventory::Unarchive to recover invalid items to continue with the remaining ones
+; When a spell item (rune or scroll) in the inventory does no longer exist in the game, loading results in a crash
+; This hook tries to recover that crash
+
+%include "inc/macros.inc"
+%include "inc/symbols.inc"
+
+%ifidn __OUTPUT_FORMAT__, bin
+    org     g1g2(0x66DC47,0x69B420,0x6AFBB9,0x70D6D9)
+%endif
+
+bits    32
+
+
+section .text   align=1                                                    ; Prevent auto-alignment
+
+        jmp     recoverInvalidItem
+        nop
+
+    %if GOTHIC_BASE_VERSION == 1 || GOTHIC_BASE_VERSION == 112
+        times 2 nop
+    %endif
+
+        ; Overwrites
+        ; %if GOTHIC_BASE_VERSION == 1 || GOTHIC_BASE_VERSION == 112
+        ;   mov     [esp+0x90-0x74], 0xFFFFFFFF
+        ; %elif GOTHIC_BASE_VERSION == 130 || GOTHIC_BASE_VERSION == 2
+        ;   jz      g1g2(,,0x6AFDA0,0x70D8C0)
+        ; %endif

src/inc/engine_g1.inc

@@ -139,6 +139,7 @@
     %define     char_timer                                0x8510CC     ; 'timer', 0
     %define     char_noOfEntries                          0x8510E4     ; 'NoOfEntries', 0
     %define     char_spawningEnabled                      0x8510BC     ; 'spawningEnabled', 0
+    %define     char_shortKey                             0x84CF50     ; 'shortKey', 0
 
     %define     char_zStartupWindowed                     0x846978     ; 'zStartupWindowed', 0
     %define     char_settings                             0x82BD98     ; 'SETTINGS', 0

src/inc/engine_g112.inc

@@ -139,6 +139,7 @@
     %define     char_timer                                0x897418     ; 'timer', 0
     %define     char_noOfEntries                          0x897430     ; 'NoOfEntries', 0
     %define     char_spawningEnabled                      0x897408     ; 'spawningEnabled', 0
+    %define     char_shortKey                             0x892FCC     ; 'shortKey', 0
 
     %define     char_zStartupWindowed                     0x88C634     ; 'zStartupWindowed', 0
 

src/inc/engine_g130.inc

@@ -140,6 +140,7 @@
     %define     char_noOfEntries                          0x8A7008     ; 'NoOfEntries', 0
     %define     char_spawningEnabled                      0x8A6FE0     ; 'spawningEnabled', 0
     %define     char_spawnFlags                           0x8A6FD4     ; 'spawnFlags', 0
+    %define     char_shortKey                             0x8A33D8     ; 'shortKey', 0
     %define     char_zStartupWindowed                     0x89C760     ; 'zStartupWindowed', 0
 
     %define     char_meatbug_mds                          0x8A47D0     ; 'Meatbug.mds', 0

src/inc/engine_g2.inc

@@ -140,6 +140,7 @@
     %define     char_noOfEntries                          0x8BAE60     ; 'NoOfEntries', 0
     %define     char_spawningEnabled                      0x8BAE38     ; 'spawningEnabled', 0
     %define     char_spawnFlags                           0x8BAE2C     ; 'spawnFlags', 0
+    %define     char_shortKey                             0x8B7200     ; 'shortKey', 0
     %define     char_zStartupWindowed                     0x8AA930     ; 'zStartupWindowed', 0
     %define     char_settings                             0x8948A0     ; 'SETTINGS', 0
     %define     char_meatbug_mds                          0x8B85F8     ; 'Meatbug.mds', 0