Implemented the COMPARE_TO method

Author: Sergejs Vinniks

src/packages/json_core.pkb

@@ -87,6 +87,7 @@ CREATE OR REPLACE PACKAGE BODY json_core IS
         default_message_resolver.register_message('JDC-00048', 'Builder not specified!');
         default_message_resolver.register_message('JDC-00049', 'Property value not specified!');
         default_message_resolver.register_message('JDC-00050', 'Unimplemented feature!');
+        default_message_resolver.register_message('JDC-00051', 'Right value not specified!');
     END;
 
     -- Do-nothing procedure to initialize error messages from another packages

src/packages/json_parser.pkb

@@ -715,8 +715,6 @@ CREATE OR REPLACE PACKAGE BODY json_parser IS
                 add_event('N', v_value);
             WHEN 'lfEnd' THEN
                 NULL;
-            WHEN 'lfContent' THEN
-                NULL;
             ELSE
                 -- Unexpected end of the input!
                 error$.raise('JSN-00002');

src/packages/persistent_json_store.pkb

@@ -1119,16 +1119,28 @@ CREATE OR REPLACE PACKAGE BODY persistent_json_store IS
 
         v_value := get_value(p_object_id);
 
-        IF v_value.type NOT IN ('O', 'R') THEN
+        IF v_value.type NOT IN ('O', 'R', 'A') THEN
             -- Value is not an object!
             error$.raise('JDC-00021');
         END IF;
 
-        SELECT name
-        BULK COLLECT INTO v_keys
-        FROM json_values
-        WHERE parent_id = p_object_id
-        ORDER BY name;
+        IF v_value.type = 'A' THEN
+        
+            SELECT name
+            BULK COLLECT INTO v_keys
+            FROM json_values
+            WHERE parent_id = p_object_id
+            ORDER BY TO_INDEX(name);
+            
+        ELSE
+        
+            SELECT name
+            BULK COLLECT INTO v_keys
+            FROM json_values
+            WHERE parent_id = p_object_id
+            ORDER BY name;
+            
+        END IF;
 
         RETURN v_keys;
 
@@ -1383,14 +1395,18 @@ CREATE OR REPLACE PACKAGE BODY persistent_json_store IS
             error$.raise('JDC-00034');
         END IF;
 
+        IF v_value.locked IS NULL THEN
+            RETURN;
+        END IF;
+        
         IF p_unpin_tree THEN
 
             SELECT id
             BULK COLLECT INTO v_ids_to_unpin
             FROM json_values
-            WHERE locked = 'T'
             START WITH id = p_id
             CONNECT BY PRIOR id = parent_id
+                       AND locked = 'T'
             FOR UPDATE;
 
         ELSE

src/packages/transient_json_store.pkb

@@ -482,7 +482,7 @@ CREATE OR REPLACE PACKAGE BODY transient_json_store IS
 
         v_value := get_value(p_object_id);
 
-        IF v_value.type NOT IN ('O', 'R') THEN
+        IF v_value.type NOT IN ('O', 'R', 'A') THEN
             -- Value is not an object!
             error$.raise('JDC-00021');
         END IF;
@@ -495,7 +495,12 @@ CREATE OR REPLACE PACKAGE BODY transient_json_store IS
         WHILE v_name LIKE v_pattern LOOP
 
             v_keys.EXTEND(1);
-            v_keys(v_keys.COUNT) := v_values(v_value_child_ids(v_name)).name;
+            
+            IF v_value.type = 'A' THEN
+                v_keys(v_keys.COUNT) := v_values(v_value_child_ids(v_name)).name;
+            ELSE
+                v_keys(v_keys.COUNT) := NVL(LTRIM(v_values(v_value_child_ids(v_name)).name, '0'), '0');
+            END IF;
 
             v_name := v_value_child_ids.NEXT(v_name);
 
@@ -1052,8 +1057,6 @@ CREATE OR REPLACE PACKAGE BODY transient_json_store IS
 
             PROCEDURE visit_next IS
 
-                v_parent_value_id NUMBER;
-                
                 v_next_sibling_element_i PLS_INTEGER;
                 v_next_sibling_element json_core.t_query_element;
 
@@ -1196,6 +1199,10 @@ CREATE OR REPLACE PACKAGE BODY transient_json_store IS
                     v_name := get_bind_value(v_element.bind_number);
                 END IF;
 
+                IF v_parent_value_id > 0 AND v_values(v_parent_value_id).type = 'A' THEN
+                    v_name := LPAD(v_name, 12, '0');
+                END IF;
+                
                 v_name := v_parent_value_id || '-' || v_name;
 
                 IF v_value_child_ids.EXISTS(v_name) THEN

src/types/t_json.tpb

@@ -1670,4 +1670,193 @@ CREATE OR REPLACE TYPE BODY t_json IS
         unpin(':i', p_unpin_tree, bind(p_index));
     END;
 
+    -- Value comparison 
+    
+    MEMBER FUNCTION compare_to (
+        p_value IN t_json
+    )
+    RETURN t_json_mismatches IS
+    
+        v_path t_varchars;
+        v_mismatches t_json_mismatches;
+        
+        PROCEDURE add_mismatch (
+            p_code IN VARCHAR2
+        ) IS
+        BEGIN
+            v_mismatches.EXTEND(1);
+            v_mismatches(v_mismatches.COUNT) := t_json_mismatch(v_path, p_code);
+        END;
+        
+        PROCEDURE push_name (
+            p_name IN VARCHAR2
+        ) IS
+        BEGIN
+            v_path.EXTEND(1);
+            v_path(v_path.COUNT) := p_name;
+        END;
+        
+        PROCEDURE pop_name IS
+        BEGIN
+            v_path.TRIM(1);
+        END;
+        
+        PROCEDURE visit_value (
+            p_left IN t_json,
+            p_right IN t_json
+        ) IS
+        
+            v_left_type CHAR;
+            v_left_value VARCHAR2(4000);
+            
+            v_right_type CHAR;
+            v_right_value VARCHAR2(4000);
+            
+            v_parent_id NUMBER;
+            
+            v_left_keys t_varchars;
+            v_right_keys t_varchars;
+            
+            v_left_i PLS_INTEGER;
+            v_right_i PLS_INTEGER;
+            
+            v_left_key VARCHAR2(4000);
+            v_right_key VARCHAR2(4000);
+            
+            v_compare PLS_INTEGER;
+            
+            PROCEDURE missing_left IS
+            BEGIN
+            
+                push_name(v_right_key);
+                add_mismatch('ML');
+                pop_name;
+                        
+                v_right_i := v_right_i + 1;
+                
+            END;
+            
+            PROCEDURE missing_right IS
+            BEGIN
+            
+                push_name(v_left_key);
+                add_mismatch('MR');
+                pop_name;
+                        
+                v_left_i := v_left_i + 1;
+            
+            END;
+            
+            PROCEDURE compare_keys IS
+            BEGIN
+            
+                IF v_left_key = v_right_key THEN
+                    v_compare := 0;
+                ELSIF v_left_type = 'A' THEN
+                    IF LPAD(v_left_key, 12, '0') > LPAD(v_right_key, 12, '0') THEN
+                        v_compare := 1;
+                    ELSE
+                        v_compare := -1;
+                    END IF;
+                ELSE
+                    IF v_left_key > v_right_key THEN
+                        v_compare := 1;
+                    ELSE
+                        v_compare := -1;
+                    END IF;
+                END IF;
+            
+            END;
+            
+        BEGIN
+        
+            p_left.dump(v_parent_id, v_left_type, v_left_value);
+            p_right.dump(v_parent_id, v_right_type, v_right_value);
+        
+            IF v_left_type != v_right_type THEN
+            
+                add_mismatch('TM');
+                
+            ELSIF v_left_type IN ('S', 'N', 'B') THEN
+            
+                IF v_left_value != v_right_value THEN
+                    add_mismatch('VM');
+                END IF;
+                
+            ELSIF v_left_type != 'E' THEN
+            
+                v_left_keys := p_left.get_keys; 
+                v_right_keys := p_right.get_keys;
+                
+                v_left_i := 1;
+                v_right_i := 1;
+                
+                WHILE v_left_i <= v_left_keys.COUNT 
+                      OR v_right_i <= v_right_keys.COUNT 
+                LOOP
+                
+                    IF v_left_i > v_left_keys.COUNT THEN
+                    
+                        v_right_key := v_right_keys(v_right_i);
+                        missing_left;
+                        
+                    ELSIF v_right_i > v_right_keys.COUNT THEN
+                        
+                        v_left_key := v_left_keys(v_left_i);
+                        missing_right;
+                            
+                    ELSE
+                    
+                        v_left_key := v_left_keys(v_left_i);
+                        v_right_key := v_right_keys(v_right_i);
+                        compare_keys;
+                        
+                        IF v_compare = -1 THEN
+                        
+                            missing_right;
+                            
+                        ELSIF v_compare = 1 THEN
+                        
+                            missing_left;
+                        
+                        ELSE
+                        
+                            push_name(v_left_key);
+                            
+                            visit_value(
+                                p_left.get(':name', bind(v_left_key)), 
+                                p_right.get(':name', bind(v_right_key))
+                            );
+                            
+                            pop_name;
+                            
+                            v_left_i := v_left_i + 1;
+                            v_right_i := v_right_i + 1;
+                        
+                        END IF;    
+                        
+                    END IF;
+                
+                END LOOP;
+                
+            END IF;
+            
+        END;
+        
+    BEGIN
+    
+        IF p_value IS NULL THEN
+            -- Right value not specified!
+            error$.raise('JDC-00051');
+        END IF;
+    
+        v_path := t_varchars();
+        v_mismatches := t_json_mismatches();
+        
+        visit_value(self, p_value);
+    
+        RETURN v_mismatches;
+    
+    END;
+    
 END;

src/types/t_json.tps

@@ -709,7 +709,14 @@ CREATE OR REPLACE TYPE t_json IS OBJECT (
         self IN t_json,
         p_index IN NUMBER,
         p_unpin_tree IN BOOLEAN := FALSE
+    ),
+    
+    -- Value comparison 
+    
+    MEMBER FUNCTION compare_to (
+        p_value IN t_json
     )
+    RETURN t_json_mismatches
 
 )
 NOT FINAL

src/types/t_json_mismatch.tps

@@ -0,0 +1,4 @@
+CREATE OR REPLACE TYPE t_json_mismatch IS OBJECT (
+    path t_varchars,
+    mismatch VARCHAR2(2)
+)

src/types/t_json_mismatches.tps

@@ -0,0 +1 @@
+CREATE OR REPLACE TYPE t_json_mismatches IS TABLE OF t_json_mismatch    

test/json_parser.js

@@ -16,6 +16,18 @@
 
 suite("Invalid JSON handling", function() {
 
+    test("Empty JSON", function() {
+    
+        expect(function() {
+        
+            database.call("json_parser.parse", {
+                p_content: null
+            });
+        
+        }).to.throw(/JSN-00002/);
+    
+    });
+
     test("Invalid start of JSON", function() {
 
         expect(function() {
@@ -321,16 +333,6 @@ suite("Invalid JSON handling", function() {
 
 suite("Scalar value tests", function() {
 
-    test("Empty document", function() {
-    
-        var events = database.call("json_parser.parse", {
-            p_content: null
-        });
-
-        expect(events).to.eql([]);
-
-    });
-
     test("String value", function() {
 
         var events = database.call("json_parser.parse", {

test/t_persistent_json/compare_to.js

@@ -0,0 +1,4 @@
+let implementationPackage = "persistent_json_store";
+let implementationType = "t_persistent_json";
+
+load("test/templates/implementation_type/compare_to.js.tpl");

test/t_persistent_json/get_table.js

@@ -0,0 +1,4 @@
+let implementationPackage = "persistent_json_store";
+let implementationType = "t_persistent_json";
+
+load("test/templates/implementation_type/get_table.js.tpl");

test/t_transient_json/compare_to.js

@@ -0,0 +1,4 @@
+let implementationPackage = "transient_json_store";
+let implementationType = "t_transient_json";
+
+load("test/templates/implementation_type/compare_to.js.tpl");

test/t_transient_json/get_table.js

@@ -0,0 +1,4 @@
+let implementationPackage = "transient_json_store";
+let implementationType = "t_transient_json";
+
+load("test/templates/implementation_type/get_table.js.tpl");