-
Notifications
You must be signed in to change notification settings - Fork 3
/
Copy pathlambda-gc.rkt
287 lines (253 loc) · 10.5 KB
/
lambda-gc.rkt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
;; A Redex model of the lambda-gc language from Morrisett, Felleisen,
;; and Harper, "Abstract Models of Memory Management"
;; (http://www.cs.cmu.edu/~rwh/papers/gc/fpca95.pdf).
#lang racket
(require redex)
(define-language lambda-gc
;; Programs.
(Var variable-not-otherwise-mentioned)
(Int number)
(Exp Var Int (pair Exp_1 Exp_2) (proj1 Exp) (proj2 Exp) (lambda (Var) Exp)
(Exp_1 Exp_2))
(Hval Int (pair Var_1 Var_2) (lambda (Var) Exp))
(Heap ((Var Hval) ...))
(Prog (letrec Heap in Exp))
(Ans (letrec Heap in Var))
;; Evaluation contexts and instruction expressions.
(Ctxt hole (pair Ctxt Exp) (pair Var Ctxt) (proj1 Ctxt) (proj2 Ctxt)
(Ctxt Exp) (Var Ctxt))
(Instr Hval (Proj Var) (Var Var))
(Proj proj1 proj2))
(define lambda-gc-red
(reduction-relation
lambda-gc
(--> (letrec Heap in (in-hole Ctxt Hval))
;; We use append rather than cons (here and in the app rule)
;; to match the semantics of the paper, where new bindings
;; get added at the end of the heap rather than the
;; beginning.
(letrec ,(append (term Heap) `((,(term Var) ,(term Hval))))
in (in-hole Ctxt Var))
;; Make sure that Var is a fresh variable, so we don't
;; conflict with bindings already in the heap.
(where Var ,(variable-not-in (term Heap) (term Var)))
"alloc")
(--> (letrec Heap in (in-hole Ctxt (Proj Var)))
(letrec Heap in (in-hole Ctxt (project Proj Heap Var)))
"proj")
(--> (letrec Heap in (in-hole Ctxt (Var_1 Var_2)))
(letrec
,(append (term Heap)
;; New binding on the heap: the equivalent of
;; {z = H(y)} from the paper.
`((,(term Var) ,(term (heap-lookup Heap Var_2)))))
;; Put Exp in the evaluation context, replacing any
;; occurrences of Var_3 (the binder from the lambda
;; expression on the heap) with our fresh variable Var.
in (in-hole Ctxt (subst Exp Var_3 Var)))
;; Var_1 should already be bound to a lambda expression in
;; the heap.
(where (lambda (Var_3) Exp) (heap-lookup Heap Var_1))
;; Make sure that Var is a fresh variable, so we don't
;; conflict with bindings already in the heap.
(where Var ,(variable-not-in (term Heap) (term Var)))
"app")))
(define-metafunction lambda-gc
project : Proj Heap Var -> Var
;; Use second and third, instead of first and second, because pairs
;; start with the tag 'pair.
[(project proj1 Heap Var) ,(second (term (heap-lookup Heap Var)))]
[(project proj2 Heap Var) ,(third (term (heap-lookup Heap Var)))])
(define-metafunction lambda-gc
heap-lookup : Heap Var -> Hval
[(heap-lookup Heap Var) ,(second (assq (term Var) (term Heap)))])
;; A few tests.
(define (test-suite)
(test-->> lambda-gc-red
(term (letrec () in 3))
(term (letrec ((Var 3))
in Var)))
(test-->> lambda-gc-red
(term (letrec () in (pair 3 4)))
(term (letrec ((Var 3)
(Var1 4)
(Var2 (pair Var Var1)))
in Var2)))
(test-->> lambda-gc-red
(term (letrec () in (proj1 (pair 3 4))))
(term (letrec ((Var 3)
(Var1 4)
(Var2 (pair Var Var1)))
in Var)))
;; The example from the lambda-gc TR
;; (http://www.cs.cmu.edu/~rwh/papers/gc/tr.pdf).
(test-->> lambda-gc-red
(term (letrec ((x 1)) in ((lambda (y) (proj1 y))
(pair x x))))
(term (letrec ((x 1)
(Var (lambda (y) (proj1 y)))
(Var1 (pair x x))
(Var2 (pair x x)))
in x)))
(test-->> lambda-gc-red
(term (letrec () in (pair ((lambda (x) x)
(proj2 (pair 1 2)))
((lambda (x) x)
(proj2 (pair 3 4))))))
(term (letrec ((Var (lambda (x) x))
(Var1 1)
(Var2 2)
(Var3 (pair Var1 Var2))
(Var4 2)
(Var5 (lambda (x) x))
(Var6 3)
(Var7 4)
(Var8 (pair Var6 Var7))
(Var9 4)
(Var10 (pair Var4 Var9)))
in
Var10)))
;; Naive substitution works -- here 'Var4' replaces 'x' in (lambda
;; (x) x), but it isn't a problem because the formal parameter 'x'
;; gets replaced with 'Var4' too!
(test-->> lambda-gc-red
(term (letrec () in (pair ((lambda (x)
((lambda (x) x) 3))
(proj2 (pair 1 2)))
((lambda (x) x)
(proj2 (pair 3 4))))))
;; should be a pair of 3 and 4
(term (letrec ((Var
(lambda (x)
((lambda (x) x)
3)))
(Var1 1)
(Var2 2)
(Var3
(pair Var1 Var2))
(Var4 2)
(Var5
(lambda (Var4)
Var4))
(Var6 3)
(Var7 3)
(Var8 (lambda (x) x))
(Var9 3)
(Var10 4)
(Var11
(pair Var9 Var10))
(Var12 4)
(Var13
(pair Var7 Var12)))
in
Var13)))
;; And if 'Var4' appears literally in the term, it's not a problem
;; because the variable-not-in feature in the app rule doesn't allow
;; us to pick any variable that already appears anywhere in the heap
;; at all.
(test-->> lambda-gc-red
(term (letrec () in (pair ((lambda (x)
((lambda (x)
((lambda (Var4)
x) x)) 3))
(proj2 (pair 1 2)))
((lambda (x) x)
(proj2 (pair 3 4))))))
;; should be a pair of 3 and 4
(term (letrec ((Var
(lambda (x)
((lambda (x)
((lambda (Var4)
x)
x))
3)))
(Var1 1)
(Var2 2)
(Var3
(pair Var1 Var2))
(Var5 2)
(Var6
(lambda (Var5)
((lambda (Var4)
Var5)
Var5)))
(Var7 3)
(Var8 3)
(Var9
(lambda (Var4)
Var8))
(Var10 3)
(Var11
(lambda (x) x))
(Var12 3)
(Var13 4)
(Var14
(pair Var12 Var13))
(Var15 4)
(Var16
(pair Var8 Var15)))
in
Var16)))
(test-->> lambda-gc-red
(term (letrec () in ((lambda (f)
(pair (f (pair 1 2))
(f (pair 3 4))))
(lambda (p) (proj2 p)))))
(term (letrec ((Var (lambda (f)
(pair (f (pair 1 2))
(f (pair 3 4)))))
(Var1 (lambda (p) (proj2 p)))
(Var2 (lambda (p) (proj2 p)))
(Var3 1)
(Var4 2)
(Var5 (pair Var3 Var4))
(Var6 (pair Var3 Var4))
(Var7 3)
(Var8 4)
(Var9 (pair Var7 Var8))
(Var10 (pair Var7 Var8))
(Var11 (pair Var4 Var8)))
in
Var11)))
;; If some variable is already in the heap with a particular name,
;; we don't autogenerate that name again.
(test-->> lambda-gc-red
(term (letrec ((Var 0)
(Var1 1)
(Var2 2)) in (pair Var (pair Var1 Var2))))
(term (letrec ((Var 0)
(Var1 1)
(Var2 2)
(Var3 (pair Var1 Var2))
(Var4 (pair Var Var3)))
in
Var4)))
;; And using existing names as formal parameters isn't a problem,
;; either.
(test-->> lambda-gc-red
(term (letrec ((Var 0)
(Var1 1)
(Var2 2)) in
((lambda (Var1) Var1)
(pair
Var (pair Var1 Var2)))))
(term (letrec ((Var 0)
(Var1 1)
(Var2 2)
(Var3 (lambda (Var1) Var1))
(Var4 (pair Var1 Var2))
(Var5 (pair Var Var4))
(Var6 (pair Var Var4)))
in
Var6)))
(test-results))
;; This is just dumb textual substitution. Capture-avoiding
;; substitution isn't necessary.
(define-metafunction lambda-gc
;; (subst expr old-var new-expr): Read the arguments left-to-right
;; as "expr, but with occurrences of old-var replaced with
;; new-expr".
[(subst Var_1 Var_1 any_1) any_1]
[(subst (any_2 ...) Var_1 any_1)
((subst any_2 Var_1 any_1) ...)]
[(subst any_2 Var_1 any_1) any_2])