build.gradle

plugins {
  id "groovy"
  id "com.github.hierynomus.license" version "0.12.1"
  id 'pl.allegro.tech.build.axion-release' version '1.8.3'
  id 'com.gradle.plugin-publish' version '0.10.0'
  id 'java-gradle-plugin'
}

defaultTasks 'build'

group = 'com.hierynomus.gradle.plugins'

repositories { jcenter() }

dependencies {
  compile gradleApi()
  compile localGroovy()
  compile "org.scala-lang:scala-library:2.12.1"
  compile "org.scalariform:scalariform_2.12:0.2.6"
  testCompile('org.spockframework:spock-core:1.2-groovy-2.5') {
    exclude group: 'org.codehaus.groovy', module: 'groovy-all'
  }
  testCompile 'com.netflix.nebula:nebula-test:7.1.8'
}

scmVersion {
  tag {
    prefix = 'v'
    versionSeparator = ''
  }
  hooks {
    pre 'fileUpdate', [file: 'README.adoc', pattern: { v, c -> /:plugin_version: .*/}, replacement: { v, c -> ":plugin_version: $v" }]
    pre 'commit'
  }
}

project.version = scmVersion.version

license {
  header = project.file("HEADER")
  mapping {
    java = 'SLASHSTAR_STYLE'
    groovy = 'SLASHSTAR_STYLE'
    scala = 'SLASHSTAR_STYLE'
  }
}

test {
  afterSuite { descriptor, result ->
    def indicator = "\u001B[32m✓\u001b[0m"
    if (result.failedTestCount > 0) {
      indicator = "\u001B[31m✘\u001b[0m"
    }
    logger.lifecycle("$indicator Test ${descriptor.name}; Executed: ${result.testCount}/\u001B[32m${result.successfulTestCount}\u001B[0m/\u001B[31m${result.failedTestCount}\u001B[0m")
  }
}

// This disables the pedantic doclint feature of JDK8
if (JavaVersion.current().isJava8Compatible()) {
  tasks.withType(Javadoc) {
    options.addStringOption('Xdoclint:none', '-quiet')
  }
}

task sourcesJar(type: Jar) {
  from sourceSets.main.allSource
  classifier = 'sources'
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

artifacts { archives sourcesJar, javadocJar }

gradlePlugin {
    plugins {
        scalariformPlugin {
            id = "com.github.hierynomus.scalariform"
            implementationClass = "nl.javadude.gradle.plugins.scalariform.ScalariformPlugin"
        }
    }
}

pluginBundle {
    website = "https://github.com/hierynomus/scalariform-gradle-plugin"
    vcsUrl = "https://github.com/hierynomus/scalariform-gradle-plugin.git"
    tags = [ "gradle", "plugin", "scalariform", "scala", "formatting" ]
    plugins {
        scalariformPlugin {
            displayName = "Scalariform plugin for Gradle"
            description = "Reformats Scala source code according to your configured conventions"
        }
    }
}

task forkedUploadRelease(type: GradleBuild) {
  buildFile = project.buildFile
  tasks = ["publishPlugins"]
}

project.tasks.release.dependsOn([project.tasks.build])
project.tasks.release.finalizedBy(project.tasks.forkedUploadRelease)