feat(build): #232 deploy terraform

- Add /deployTerraform to makes.nix
- Add arguments, docs, etc

Author: kamadorueda

.github/workflows/dev.yml

@@ -7,6 +7,14 @@ jobs:
       name: __all__
       with:
         args: sh -c "nix-env -if . && m . __all__"
+  deployTerraform_module:
+    runs-on: ubuntu-latest
+    steps:
+    - uses: actions/checkout@v2
+    - uses: docker://docker.io/nixos/nix:2.3.12
+      name: /deployTerraform/module
+      with:
+        args: sh -c "nix-env -if . && m . /deployTerraform/module"
   formatBash:
     runs-on: ubuntu-latest
     steps:

README.md

@@ -49,6 +49,8 @@ in just a few steps, in any technology.
         - [lintWithLizard](#lintwithlizard)
     - [Testing](#testing)
         - [testTerraform](#testterraform)
+    - [Deployment](#deployment)
+        - [deployTerraform](#deployterraform)
     - [Pinning](#pinning)
         - [inputs](#inputs)
         - [requiredMakesVersion](#requiredmakesversion)
@@ -949,7 +951,9 @@ Example `makes.nix`:
 }
 ```
 
-Example invocation: `$ m . /lintTerraform`
+Example invocation: `$ m . /lintTerraform/module1`
+
+Example invocation: `$ m . /lintTerraform/module2`
 
 ### lintWithLizard
 
@@ -1026,7 +1030,57 @@ Example `makes.nix`:
 }
 ```
 
-Example invocation: `$ m . /testTerraform`
+Example invocation: `$ m . /testTerraform/module1`
+
+Example invocation: `$ m . /testTerraform/module2`
+
+## Deployment
+
+### deployTerraform
+
+Deploy [Terraform][TERRAFORM] code
+by performing a `terraform apply`
+over the specified [Terraform][TERRAFORM] modules.
+
+Attributes:
+
+- modules (`attrsOf moduleType`): Optional.
+  Path to [Terraform][TERRAFORM] modules to lint.
+  Defaults to `{ }`.
+
+Custom Types:
+
+- moduleType (`submodule`):
+    - authentication (`listOf package`): Optional.
+      [Makes Secrets][MAKES_SECRETS] to use (if required by your module).
+      Defaults to `[ ]`.
+    - src (`str`):
+      Path to the [Terraform][TERRAFORM] module.
+    - version (`enum [ "0.12" "0.13" "0.14" "0.15" "0.16" ]`):
+      [Terraform][TERRAFORM] version your module is built with.
+
+Example `makes.nix`:
+
+```nix
+{
+  deployTerraform = {
+    modules = {
+      module1 = {
+        src = "/my/module1";
+        version = "0.12";
+      };
+      module2 = {
+        src = "/my/module2";
+        version = "0.16";
+      };
+    };
+  };
+}
+```
+
+Example invocation: `$ m . /deployTerraform/module1`
+
+Example invocation: `$ m . /deployTerraform/module2`
 
 ## Pinning
 
@@ -1766,6 +1820,8 @@ Examples:
   https://github.com/fluidattacks/makes/commit/01fcd5790dd54b117da63bcc2480437135da8bb3)
 - [feat(build): #232 lint terraform](
   https://github.com/fluidattacks/makes/commit/081835b563c712b7650dbc5bf1e306d4aff159cf)
+- [feat(build): #232 test terraform](
+  https://github.com/fluidattacks/makes/commit/571cf059b521cb97396210f9fe4659ee74f675b4)
 - [feat(build): #252 aws secrets from env](
   https://github.com/fluidattacks/makes/commit/1c9f06a809bd92d56939d5809ce46058856fdf0a)
 - [feat(build): #232 make parallel utils](

makes.nix

@@ -29,6 +29,14 @@
       };
     };
   };
+  deployTerraform = {
+    modules = {
+      module = {
+        src = "/test/terraform/module";
+        version = "0.13";
+      };
+    };
+  };
   formatBash = {
     enable = true;
     targets = [ "/" ];

src/args/default.nix

@@ -14,6 +14,7 @@ let
     asBashArray = args: "( ${lib.strings.escapeShellArgs args} )";
     asContent = import ./as-content/default.nix;
     deployContainerImage = import ./deploy-container-image/default.nix args;
+    deployTerraform = import ./deploy-terraform/default.nix args;
     fakeSha256 = lib.fakeSha256;
     fetchGithub = import ./fetchers/github.nix args;
     fetchNixpkgs = import ./fetchers/nixpkgs.nix args;

src/args/deploy-terraform/default.nix

@@ -0,0 +1,25 @@
+{ __nixpkgs__
+, makeScript
+, makeTerraformEnvironment
+, ...
+}:
+{ authentication
+, name
+, version
+, src
+, ...
+}:
+makeScript {
+  entrypoint = ./entrypoint.sh;
+  replace = {
+    __argSrc__ = src;
+  };
+  name = "deploy-terraform-for-${name}";
+  searchPaths = {
+    source = [
+      (makeTerraformEnvironment {
+        inherit version;
+      })
+    ] ++ authentication;
+  };
+}

src/args/deploy-terraform/entrypoint.sh

@@ -0,0 +1,19 @@
+# shellcheck shell=bash
+
+function main {
+  local args=(
+    -refresh=true
+  )
+
+  cd "$(mktemp -d)" \
+    && copy '__argSrc__' . \
+    && info Initializing '__argSrc__' \
+    && terraform init \
+    && info Applying '__argSrc__' \
+    && if running_in_ci_cd_provider; then
+      args+=(-auto-approve)
+    fi \
+    && terraform apply "${args[@]}"
+}
+
+main "${@}"

src/evaluator/modules/outputs/builtins/default.nix

@@ -3,6 +3,7 @@ args:
   imports = [
     (import ./__all__/default.nix args)
     (import ./deploy-container-image/default.nix args)
+    (import ./deploy-terraform/default.nix args)
     (import ./format-bash/default.nix args)
     (import ./format-markdown/default.nix args)
     (import ./format-nix/default.nix args)

src/evaluator/modules/outputs/builtins/deploy-terraform/default.nix

@@ -0,0 +1,53 @@
+{ __nixpkgs__
+, __toModuleOutputs__
+, deployTerraform
+, path
+, ...
+}:
+{ config
+, lib
+, ...
+}:
+let
+  makeOutput = name: { authentication, src, version }: {
+    name = "/deployTerraform/${name}";
+    value = deployTerraform {
+      inherit authentication;
+      inherit name;
+      src = path src;
+      inherit version;
+    };
+  };
+in
+{
+  options = {
+    deployTerraform = {
+      modules = lib.mkOption {
+        default = { };
+        type = lib.types.attrsOf (lib.types.submodule (_: {
+          options = {
+            authentication = lib.mkOption {
+              default = [ ];
+              type = lib.types.listOf lib.types.package;
+            };
+            src = lib.mkOption {
+              type = lib.types.str;
+            };
+            version = lib.mkOption {
+              type = lib.types.enum [
+                "0.12"
+                "0.13"
+                "0.14"
+                "0.15"
+                "0.16"
+              ];
+            };
+          };
+        }));
+      };
+    };
+  };
+  config = {
+    outputs = __toModuleOutputs__ makeOutput config.deployTerraform.modules;
+  };
+}