feat(nixos): add support for gitea/forgejo (#179)

Co-authored-by: seth <getchoo@tuta.io> Co-authored-by: isabel <isabel@isabelroses.com>
catppuccin · Feb 19, 2025 · b1ff2a6 · b1ff2a6
1 parent 24dac16
commit b1ff2a6
Show file tree

Hide file tree

Showing 4 changed files with 97 additions and 0 deletions.
diff --git a/modules/nixos/all-modules.nix b/modules/nixos/all-modules.nix
@@ -1,5 +1,6 @@
 [
   ./fcitx5.nix
+  ./gitea.nix
   ./grub.nix
   ./plymouth.nix
   ./sddm.nix

diff --git a/modules/nixos/gitea.nix b/modules/nixos/gitea.nix
@@ -0,0 +1,88 @@
+{ catppuccinLib }:
+{
+  lib,
+  config,
+  ...
+}:
+let
+  inherit (config.catppuccin) sources;
+
+  valuesFromEnum =
+    enum: if lib.isList enum.functor.payload then enum.functor.payload else enum.functor.payload.values;
+
+  supportedForges = [
+    "gitea"
+    "forgejo"
+  ];
+
+  builtinThemes = {
+    gitea = [
+      "auto"
+      "gitea"
+      "arc-greeen"
+    ];
+
+    forgejo = [
+      "forgejo-auto"
+      "forgejo-light"
+      "forgejo-dark"
+      "gitea-auto"
+      "gitea-light"
+      "gitea-dark"
+      "forgejo-auto-deuteranopia-protanopia"
+      "forgejo-light-deuteranopia-protanopia"
+      "forgejo-dark-deuteranopia-protanopia"
+      "forgejo-auto-tritanopia"
+      "forgejo-light-tritanopia"
+      "forgejo-dark-tritanopia"
+    ];
+  };
+in
+{
+  options.catppuccin = lib.genAttrs supportedForges (
+    name:
+    catppuccinLib.mkCatppuccinOption {
+      inherit name;
+      accentSupport = true;
+    }
+  );
+
+  config = lib.mkMerge (
+    map (
+      forge:
+      let
+        cfg = config.catppuccin.${forge};
+
+        inherit (config.services.${forge}) customDir;
+        themeDir =
+          if lib.versionAtLeast config.services.${forge}.package.version "1.21.0" then
+            "${customDir}/public/assets/css"
+          else
+            "${customDir}/public/css";
+      in
+      lib.mkIf cfg.enable {
+        systemd.tmpfiles.settings."10-catppuccin-${forge}-theme" = {
+          ${themeDir}."L+" = {
+            argument = toString sources.gitea;
+          };
+
+          ${dirOf themeDir}.d = {
+            inherit (config.services.${forge}) user group;
+          };
+        };
+
+        services.${forge}.settings.ui = {
+          DEFAULT_THEME = "catppuccin-${cfg.flavor}-${cfg.accent}";
+          THEMES = lib.concatStringsSep "," (
+            builtinThemes.${forge}
+            ++ (lib.mapCartesianProduct ({ flavor, accent }: "catppuccin-${flavor}-${accent}") (
+              lib.mapAttrs (lib.const valuesFromEnum) {
+                inherit (catppuccinLib.types) accent flavor;
+              }
+            ))
+          );
+        };
+      }
+    ) supportedForges
+  );
+}
diff --git a/modules/tests/nixos.nix b/modules/tests/nixos.nix
@@ -31,6 +31,8 @@ testers.runNixOSTest {
           enable = true;
           package = pkgs.kdePackages.sddm; # our module/the upstream port requires the qt6 version
         };
+        forgejo.enable = true;
+        gitea.enable = true;
         xserver.enable = true; # required for sddm
       };
 

diff --git a/pkgs/gitea/package.nix b/pkgs/gitea/package.nix
@@ -0,0 +1,6 @@
+{ fetchzip }:
+fetchzip {
+  url = "https://github.com/catppuccin/gitea/releases/download/v0.4.1/catppuccin-gitea.tar.gz";
+  hash = "sha256-14XqO1ZhhPS7VDBSzqW55kh6n5cFZGZmvRCtMEh8JPI=";
+  stripRoot = false;
+}