Initial commit

Author: biochimia

LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2020 João Abecasis
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

README.md

@@ -0,0 +1,31 @@
+# vim-jslt
+
+[JSLT](https://github.com/schibsted/jslt) filetype plugin for Vim.
+
+## Install
+
+To install via Vim plugin managers:
+
+### Vundle
+
+```viml
+Plugin 'biochimia/vim-jslt'
+```
+
+### vim-plug
+
+```viml
+Plug 'biochimia/vim-jslt'
+```
+
+### Pathogen
+
+```sh
+git clone https://github.com/biochimia/vim-jslt ~/.vim/bundle/vim-jslt
+```
+
+## More Info
+
+For more info on JSLT:
+* Repository: https://github.com/schibsted/jslt
+* Playground: http://www.garshol.priv.no/jslt-demo

ftdetect/jslt.vim

@@ -0,0 +1 @@
+autocmd BufRead,BufNewFile *.jslt set filetype=jslt

ftplugin/jslt.vim

@@ -0,0 +1,18 @@
+" Vim filetype plugin
+" Language: JSLT
+" Maintainer: João Abecasis <joao@abecasis.name>
+" URL: https://github.com/schibsted/jslt
+" Latest Revision: 13 October 2020
+
+setlocal suffixesadd=.jslt
+setlocal iskeyword=@,$,-,_,48-57,192-255
+setlocal include="^\s*import\>"
+setlocal comments=://
+setlocal commentstring=//\ %s
+
+" Script for filetype switching to undo the local stuff we may have changed
+let b:undo_ftplugin = 'setlocal suffixesadd<'
+  \ . '|setlocal iskeyword<'
+  \ . '|setlocal include<'
+  \ . '|setlocal comments<'
+  \ . '|setlocal commentstring<'

syntax/jslt.vim

@@ -0,0 +1,59 @@
+" Vim syntax file
+" Language: JSLT
+" Maintainer: João Abecasis <joao@abecasis.name>
+" URL: https://github.com/schibsted/jslt
+" Latest Revision: 12 October 2020
+
+" quit when a syntax file was already loaded
+if exists("b:current_syntax")
+  finish
+endif
+
+let s:cpo_save = &cpo
+set cpo&vim
+
+syn match   jsltStringEscape    +\\"\|\\\\+ contained
+syn region  jsltString          start=+"+ skip=+\\\"\|\\\\+ end=+"+ contains=jsltStringEscape
+
+syn match   jsltNumber          "\<-\?\%(0\|[1-9]\d*\)\%(\.\d\+\)\?\%([Ee][+-]\?\d\+\)\?\>"
+
+syn keyword jsltConditional     if else
+syn keyword jsltBoolean         true false
+syn keyword jsltNull            null
+syn keyword jsltRepeat          for
+syn keyword jsltOperator        and or
+syn match   jsltOperator        "\%(=\|==\|!=\|>=\|>\|<\|<=\|+\|-\|*\|\/\||\)"
+syn match   jsltIdentifier      "\h\%(\w\|-\)*" display contained
+syn keyword jsltStatement       let nextgroup=jsltIdentifier skipwhite
+syn keyword jsltStatement       def nextgroup=jsltIdentifier skipwhite
+
+syn keyword jsltImport          import nextgroup=jsltImportSource skipwhite
+syn region  jsltImportSource    start=+"+ skip=+\\\"\|\\\\+ end=+"+ contains=jsltStringEscape nextgroup=jsltImportName skipwhite
+syn keyword jsltImportName      as contained nextgroup=jsltIdentifier skipwhite
+
+syn keyword jsltCommentTodo     FIXME NOTE TBD TODO XXX contained
+syn match   jsltLineComment     "\/\/.*" contains=@Spell,jsltCommentTodo
+
+" The default highlight links.  Can be overridden later.
+hi def link jsltStatement       Statement
+hi def link jsltImportSource    String
+hi def link jsltImportName      Statement
+hi def link jsltConditional     Conditional
+hi def link jsltRepeat          Repeat
+hi def link jsltOperator        Operator
+hi def link jsltImport          Include
+hi def link jsltIdentifier      Function
+hi def link jsltLineComment     Comment
+hi def link jsltCommentTodo     Todo
+hi def link jsltNull            Constant
+hi def link jsltBoolean         Boolean
+hi def link jsltString          String
+hi def link jsltStringEscape    Special
+hi def link jsltNumber          Number
+
+let b:current_syntax = "jslt"
+
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+" vim:set shiftwidth=2 softtabstop=2 tabstop=2 expandtab: