build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group 'br.dev.brunoxkk0'
version '1.0.8'

sourceCompatibility = 1.8

repositories {

    mavenCentral()

    maven {
        name = 'enginehub'
        url = 'https://maven.enginehub.org/repo/'
    }

    maven {
        name = 'jitpack'
        url = 'https://jitpack.io'
    }

    maven {
        name = 'Sonatype OSS'
        url = 'https://oss.sonatype.org/content/repositories/snapshots'
    }

    maven {
        name = 'CodeMC'
        url = 'https://repo.codemc.io/'
    }

    maven {
        name = 'sk89q'
        url = 'https://maven.sk89q.com/repo/'
    }

}

dependencies {

    annotationProcessor 'com.github.bsideup.jabel:jabel-javac-plugin:0.4.2'
    compileOnly 'com.github.bsideup.jabel:jabel-javac-plugin:0.4.2'

    annotationProcessor 'org.projectlombok:lombok:1.18.28'
    compileOnly 'org.projectlombok:lombok:1.18.28'

    compileOnly 'com.sk89q.worldedit:worldedit-bukkit:6.1.5'
    compileOnly 'com.sk89q.worldguard:worldguard-legacy:6.2'

    compileOnly 'com.github.MilkBowl:VaultAPI:1.7.1'

    compileOnly 'com.github.CrucibleMC:Crucible:81fcb90bad'

    annotationProcessor 'net.java.dev.jna:jna-platform:5.13.0'

    implementation 'org.reflections:reflections:0.10.2'
    implementation 'com.electronwill.night-config:hocon:3.6.0'

    implementation 'org.slf4j:slf4j-nop:1.7.32'

    implementation 'io.lettuce:lettuce-core:6.2.6.RELEASE'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.12.7.1'

}

configure([tasks.compileJava]) {
    sourceCompatibility = 17 // for the IDE support
    options.release = 8
    options.encoding = 'UTF-8'

    javaCompiler = javaToolchains.compilerFor {
        languageVersion = JavaLanguageVersion.of(17)
    }
}


compileJava.options.encoding = 'UTF-8'
tasks.withType(JavaCompile) {
    options.encoding = 'UTF-8'
}

processResources {
    def props = [version: version]
    inputs.properties props
    filteringCharset 'UTF-8'
    filesMatching('plugin.yml') {
        expand props
    }
}

shadowJar {

    relocate("org.slf4j.nop",                   "org.slf4j.nop")

    relocate("com.electronwill.nightconfig",    "br.dev.brunoxkk0.syrxmccore.libs.com.electronwill.nightconfig")
    relocate("com.typesafe",                    "br.dev.brunoxkk0.syrxmccore.libs.com.typesafe")
    relocate("javassist",                       "br.dev.brunoxkk0.syrxmccore.libs.javassist")
    relocate("javax.annotation ",               "br.dev.brunoxkk0.syrxmccore.libs.javax.annotation")
    relocate("org.reflections",                 "br.dev.brunoxkk0.syrxmccore.libs.org.reflections")
    relocate("org.apache",                      "br.dev.brunoxkk0.syrxmccore.libs.org.apache")
    relocate("org.slf4j",                       "br.dev.brunoxkk0.syrxmccore.libs.org.slf4j")

    relocate("com.fasterxml.jackson",   "br.dev.brunoxkk0.syrxmccore.libs.com.fasterxml.jackson")
    relocate("reactor",                 "br.dev.brunoxkk0.syrxmccore.libs.reactor")
    relocate("io.netty",                "br.dev.brunoxkk0.syrxmccore.libs.io.netty")
    relocate("io.lettuce",              "br.dev.brunoxkk0.syrxmccore.libs.io.lettuce")
    relocate("org.reactivestreams",     "br.dev.brunoxkk0.syrxmccore.libs.org.reactivestreams")

    archiveClassifier.set("")

}

build {
    dependsOn(shadowJar)
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId project.group
            artifactId project.name
            version project.version
            from components.java
        }
    }
}