Bump binwalk to v3

[felbinger]

Project description

The firmware analysis tool has been rewritten in rust, according to ReFirmLabs/binwalk#691 the first release will be created in the next days.

Metadata

• homepage URL: https://github.com/ReFirmLabs/binwalk
• source URL: https://github.com/ReFirmLabs/binwalk
• license: mit
• platforms: unix, linux, darwin, ...

---

Add a 👍 reaction to issues you find important.

[felbinger]

This works so far:

{
  lib,
  rustPlatform,
  fetchFromGitHub,
  pkg-config,
  fontconfig,
  bzip2,
}:

rustPlatform.buildRustPackage rec {
  pname = "binwalk";
  version = "3.1.0";

  src = fetchFromGitHub {
    owner = "ReFirmLabs";
    repo = "binwalk";
    rev = "4c71ce48bda3c8f0214d56ad6c18c3a833a8dd29";
    hash = "sha256-5RgjspfTiiLyIyxr9BEHSlmjlWP02MKuSkMlQS482/E=";
  };

  cargoLock = {
    lockFile = ./Cargo.lock;
  };

  nativeBuildInputs = [ pkg-config ];

  buildInputs = [
    fontconfig.dev
    bzip2.out
  ];

  # skip broken tests
  checkFlags = [
    "--skip=binwalk::Binwalk"
    "--skip=binwalk::Binwalk::analyze"
    "--skip=binwalk::Binwalk::extract"
    "--skip=binwalk::Binwalk::scan"
  ];

  meta = {
    description = "Firmware Analysis Tool";
    homepage = "https://github.com/ReFirmLabs/binwalk";
    changelog = "https://github.com/ReFirmLabs/binwalk/releases/tag/${src.rev}";
    license = lib.licenses.mit;
  };
}

[alexandru0-dev]

@felbinger I've come up with the same solution basically
I've just seen now that you've changed the previous message

{
  lib,
  rustPlatform,
  fetchFromGitHub,
  versionCheckHook,
  pkg-config,
  fontconfig,
}:

rustPlatform.buildRustPackage rec {
  pname = "binwalk-v3";
  version = "5ef95bf9b40409a8ea6a9b0c85f52b249a3ef861";

  src = fetchFromGitHub {
    owner = "ReFirmLabs";
    repo = "binwalk";
    rev = "${version}";
    sha256 = "sha256-XBFo0g4ZJZBWdEr7LwjEq3KHz1wceOCvBE5pt8V+fBg=";
  };

  cargoHash = "sha256-3DCwnthZEF7DAo5unhQ9WlHcToGUtJDfJrVPxvvmxWc=";

  nativeBuildInputs = [ pkg-config ];
  buildInputs = [ fontconfig ];

  # skip broken tests
  checkFlags = [
    "--skip=binwalk::Binwalk"
    "--skip=binwalk::Binwalk::analyze"
    "--skip=binwalk::Binwalk::extract"
    "--skip=binwalk::Binwalk::scan"
  ];

  passthru.tests.can-print-version = [ versionCheckHook ];

  meta = {
    description = "Firmware Analysis Tool";
    homepage = "https://github.com/ReFirmLabs/binwalk";
    license = lib.licenses.mit;
    maintainers = with lib.maintainers; [ alexandru0-dev ];
  };
}