grammar.txt

statements
        : NEWLINE* statement (NEWLINE+ statement)* NEWLINE*

statement
        : KEYWORD:RETURN expr?
        : KEYWORD:CONTINUE
        : KEYWORD:BREAK
        : expr

expr
        : KEYWORD:VAR IDENTIFIER EQ expr
        : comp-expr ((KEYWORD:AND|KEYWORD:OR) comp-expr)*

comp-expr
        : NOT comp-expr
        : arith-expr ((EE|GT|LT|GTE|LTE|NE) arith-expr)*

arith-expr
        : term ((PLUS|MINUS) term)*

term
        : factor ((MUL|DIV|QEDIV|MOD) factor)*

factor
        : (PLUS|MINUS) factor
        : power

power
        : call (POW factor)*

call
        : atom (LPAREN (expr (COMMA expr)*)? RPAREN)?

atom
        : NUM|STRING|IDENTIFIER
        : LPAREN expr RPAREN
        : list-expr
        : if-expr
        : for-expr
        : while-expr
        : function-def

list-expr
        : LSQUARE (expr (COMMA expr)*)? RSQUARE

if-expr
        : KEYWORD:IF expr KEYWORD:THEN
          (statement if-expr-b|if-expr-c?)
        | (NEWLINE statements KEYWORD:END|if-expr-b|if-expr-c)

if-expr-b
        : KEYWORD:ELIF expr KEYWORD:THEN
          (statement if-expr-b|if-expr-c?)
        | (NEWLINE statements KEYWORD:END|if-expr-b|if-expr-c)

if-expr-c
        : KEYWORD:ELSE
          statement
        | (NEWLINE statements KEYWORD:END)

for-expr
        : KEYWORD:FOR IDENTIFIER EQ expr KEYWORD:TO expr
          (KEYWORD:STEP expr)? KEYWORD:THEN 
          statement
        | (NEWLINE statements KEYWORD:END)

while-expr
        : KEYWORD:WHILE expr THEN 
          statement
        | (NEWLINE statements KEYWORD:END)

function-def
        : KEYWORD:FUNCTION IDENTIFIER?
          LPAREN (IDENTIFIER (COMMA IDENTIFIER)*)? RPAREN
          (ARROW expr)
        | (NEWLINE statements KEYWORD:END)