build.gradle

plugins {
  id "com.github.spotbugs" version "1.5"
}

apply from: "$rootDir/gradle/checkstyle.gradle"
apply from: "$rootDir/gradle/javadoc.gradle"
apply from: "$rootDir/gradle/maven.gradle"

dependencies {
  compileOnly 'junit:junit:4.12'
  compileOnly project(':spotbugs')
  compile project(':test-harness-core')
}

task javadocJar(type: Jar) {
  classifier = 'javadoc'
  from javadoc
}

task sourcesJar(type: Jar) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

artifacts {
  archives jar, javadocJar, sourcesJar
}

uploadArchives {
  repositories {
    mavenDeployer {
      pom.project {
        name 'JUnit 4 Test Harness for SpotBugs Plugin'
        description 'A test harness library for SpotBugs plugin developers to test on JUnit4'
      }
    }
  }
}

// Module name should be reverse-DNS (com.github.spotbugs) just like package name
// http://blog.joda.org/2017/04/java-se-9-jpms-module-naming.html
ext.moduleName = 'com.github.spotbugs.test'
apply from: "$rootDir/gradle/jigsaw.gradle"

spotbugs {
  effort = "max"
  reportLevel = "high"
}